Why the internal _burn function is virtual in ERC721 but not in ERC20 and ERC1155

CJ42 · July 5, 2023, 1:08pm

I was just wondering while going through the code.

In ERC20, there is clearly this message in the comments above the function.

OpenZeppelin/openzeppelin-contracts/blob/90163661df4f7df22294fcbf82dd3f6bb5547417/contracts/token/ERC20/ERC20.sol#L289-L302


      
          /**
           * @dev Destroys a `value` amount of tokens from `account`, by transferring it to address(0).
           * Relies on the `_update` mechanism.
           *
           * Emits a {Transfer} event with `to` set to the zero address.
           *
           * NOTE: This function is not virtual, {_update} should be overridden instead
           */
          function _burn(address account, uint256 value) internal {
              if (account == address(0)) {
                  revert ERC20InvalidSender(address(0));
              }
              _update(account, address(0), value);
          }

But for 721 and 1155, there is no mention of this, and only in ERC721 the function is marked as virtual.

github.com

OpenZeppelin/openzeppelin-contracts/blob/90163661df4f7df22294fcbf82dd3f6bb5547417/contracts/token/ERC721/ERC721.sol#L313-L333


      
          function _burn(uint256 tokenId) internal virtual {
              address owner = ownerOf(tokenId);
          
              _beforeTokenTransfer(owner, address(0), tokenId, 1);
          
              // Update ownership in case tokenId was transferred by `_beforeTokenTransfer` hook
              owner = ownerOf(tokenId);
          
              // Clear approvals
              delete _tokenApprovals[tokenId];
          
              // Decrease balance with checked arithmetic, because an `ownerOf` override may
              // invalidate the assumption that `_balances[from] >= 1`.
              _balances[owner] -= 1;
          
              delete _owners[tokenId];
          
              emit Transfer(owner, address(0), tokenId);
          
              _afterTokenTransfer(owner, address(0), tokenId, 1);
          }

github.com

OpenZeppelin/openzeppelin-contracts/blob/90163661df4f7df22294fcbf82dd3f6bb5547417/contracts/token/ERC1155/ERC1155.sol#L327-L343


      
          /**
           * @dev Destroys a `value` amount of tokens of type `id` from `from`
           *
           * Emits a {TransferSingle} event.
           *
           * Requirements:
           *
           * - `from` cannot be the zero address.
           * - `from` must have at least `value` amount of tokens of type `id`.
           */
          function _burn(address from, uint256 id, uint256 value) internal {
              if (from == address(0)) {
                  revert ERC1155InvalidSender(address(0));
              }
              (uint256[] memory ids, uint256[] memory values) = _asSingletonArrays(id, value);
              _updateWithAcceptanceCheck(from, address(0), ids, values, "");
          }

Would be curious to know and understand. If anything should be changed for consistency, I am happy to open a PR.

barakman · July 5, 2023, 2:49pm

Function _burn is virtual where function _update is NOT implemented (ERC721).

Function _burn is NOT virtual where function _update is implemented (ERC20 and ERC1155).

The only "flaw" here is the comment appearing in the ERC20 code but not in the ERC1155 code:

 * NOTE: This function is not virtual, {_update} should be overridden instead

frangio · July 6, 2023, 1:52am

Code in the master branch is in development. The same change will be made in ERC721 shortly.

The lack of virtual is because overrides should be done in the _update function so they are consistently applied to mints and burns as well.

Topic		Replies	Views
Burning tokens - apparently not the owner Smart Contracts erc721	1	764	November 17, 2021
Remove burn functionality from ERC721 Contracts	2	1309	August 12, 2021
Burning an token - owner only Support	3	1142	June 18, 2021
Issues with web3 and _burn functions Contracts	2	703	May 20, 2021
ERC721 burn functionality Contracts	1	2917	February 9, 2022

Why the internal _burn function is virtual in ERC721 but not in ERC20 and ERC1155

Related topics